home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 9
/
FM Towns Free Software Collection 9.iso
/
fb386
/
game
/
samurai
/
samurai.bas
< prev
next >
Wrap
BASIC Source File
|
1994-11-16
|
2KB
|
61 lines
1000 '-------------
1010 '/samurai.bas/
1020 '-------------
1030 :
1040 SCREEN@ 1:CLS 0
1045 VIEW (0,0)-(511,255):WINDOW (0,0)-(511,255)
1050 DEFINT A-Z
1055 BI=2:PE=1
1060 DIM GR(23040),G1(5120),SW0(13005),SW1(10659),SW2(14162),TUKE(5757)
1070 LOAD@ "kin.snd",SW0
1072 LOAD@ "zan1.snd",SW1
1074 LOAD@ "zan2.snd",SW2
1075 LOAD@ "tatan.snd",TUKE
1076 LOAD@ "samurai.tif",(0,0)
1080 FOR I=0 TO 9:L=(I\4)*48:M=(I MOD 4)*48
1090 GET@A (L,M)-(L+47,M+47),GR,(L*4+M)*48
1100 NEXT
1110 GET@A (96,96)-(175,159),G1
1115 *STAT
1120 CLS 0
1125 DX=160-40*BI:DY=120-32*BI:IF DY<0 THEN DY=0
1130 :VIEW (DX,DY)-(511,255):WINDOW(0,0)-((511-DX)\BI,(255-DY)\BI)
1140 PUT@A (0,0)-(79,63),G1,,BI,BI
1150 LOCATE 35,16:PRINT "push [run]"
1160 WHILE PTRIG(1)<>4
1162 PT=PTRIG(1)
1164 IF PT<>PBA1 THEN PBA1=PT:PE=PE-(PT=2):IF PE>2 THEN PE=0
1166 LOCATE 35,14:PRINT "player";PE
1168 IF PT<>PBA2 THEN PBA2=PT: IF PT=8 THEN :BI=BI-(PT=8)+(BI=4)*4:GOTO *STAT
1170 WEND:PCMPLAY TUKE,127
1175 RANDOMIZE TIME
1180 X=16*BI
1190 CLS 4
1200 PUT@A (X,X)-(X+47,X+47),GR,,BI,BI,,(0+2*4)*48^2
1210 D1=0:D2=0:W=4
1220 :WAIT 50
1250 WHILE -1 '-----------------------------------------------
1260 WAIT 20
1270 LINE (16,16)-(16+47,16+39),PSET,7,BF
1275 WAIT 2
1280 IF PE<1 THEN P1=INT(RND(1)*3+1) ELSE P1=PTRIG(1)+1:IF P1>3 THEN P1=1
1290 IF PE<2 THEN P2=INT(RND(2)*3+1) ELSE P2=PTRIG(2)+1:IF P2>3 THEN P2=1
1300 IF P1=P2 THEN P=2:G=1:W=1:PCMPLAY SW0,127:GOTO *E
1310 IF P1=P2+1+(P1=1)*3 THEN D1=D1+P2*2:P=1:G=P2-1:W=P2+1 ELSE D2=D2+P1*2:P=0:G=P1-1:W=P1+1
1315 IF G=2 THEN PCMPLAY SW2,127 ELSE PCMPLAY SW1,127
1320 *E
1330 PUT@A (X,X)-(X+47,X+47),GR,,BI,BI,,(G+P*4)*48^2
1340 LINE (40-D1,5)-(41+D2,7),PSET,0,BF
1350 WAIT W*15
1360 PUT@A (X,X)-(X+47,X+47),GR,,BI,BI,,(0+2*4)*48^2
1365 IF D1>30 THEN *END
1366 IF D2>30 THEN *END
1370 WEND '-----------------------------------------------------
1400 *END
1410 WAIT 100:PCMPLAY TUKE,127
1420 PUT@A (X,X)-(X+47,X+47),GR,,BI,BI,,(3+P*4)*48^2
1430 LOCATE 36,11:PRINT "勝者";P+1;"P"
1435 WAIT 200
1440 WHILE PTRIG(1)=0:WEND
1450 GOTO *STAT